wterrain
Prev | Orchestra Opcodes and Operators | Next

## wterrain

wterrain — A simple wave-terrain synthesis opcode.

## Description

A simple wave-terrain synthesis opcode.

## Syntax

    aout wterrain kamp, kpch, k_xcenter, k_ycenter, k_xradius, k_yradius, \
          itabx, itaby

## Initialization

itabx, itaby -- The two tables that define the terrain.

## Performance

The output is the result of drawing an ellipse with axes k_xradius and k_yradius centered at (k_xcenter, k_ycenter), and traversing it at frequency kpch.

## Examples

Here is an example of the wterrain opcode. It uses the file wterrain.csd.

Example 1000. Example of the wterrain opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o wterrain.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    instr 1
    kdclk   linseg  0, 0.01, 1, p3-0.02, 1, 0.01, 0
    kcx     line    0.1, p3, 1.9
    krx     linseg  0.1, p3/2, 0.5, p3/2, 0.1
    kpch    line    cpspch(p4), p3, p5 * cpspch(p4)
    a1      wterrain    10000, kpch, kcx, kcx, -krx, krx, p6, p7
    a1      dcblock a1
            out     a1*kdclk
    endin

    </CsInstruments>
    <CsScore>

    f1      0       8192    10      1 0 0.33 0 0.2 0 0.14 0 0.11
    f2      0       4096    10      1

    i1      0       4       7.00 1 1 1
    i1      4       4       6.07 1 1 2
    i1      8       8       6.00 1 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Matthew Gillard
New in version 4.19

Prev | Up | Next
wrap | Home | xadsr