strsub
Prev | Orchestra Opcodes and Operators | Next

## strsub

strsub — Extract a substring

## Description

Return a substring of the source string. strsub runs at init time only.

## Syntax

    Sdst strsub Ssrc[, istart[, iend]]

## Initialization

istart (optional, defaults to 0) -- start position in Ssrc, counting from 0. A negative value means the end of the string.

iend (optional, defaults to -1) -- end position in Ssrc, counting from 0. A negative value means the end of the string. If iend is less than istart, the output is reversed.

## Examples

Here is an example of the strsub opcode. It uses the file strsub.csd.

Example 835. Example of the strsub opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     ;;;-d     RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o strsub.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    ; By: Jonathan Murphy 2007

    instr 1
        Smember strget p4

        ; Parse Smember
        istrlen    strlen   Smember
        idelimiter strindex Smember, ":"

        S1    strsub Smember, 0, idelimiter  ; "String1"
        S2    strsub Smember, idelimiter + 1, istrlen  ; "String2"

        printf "First string: %s\nSecond string: %s\n", 1, S1, S2

    endin

    </CsInstruments>
    <CsScore>
    i 1 0 1 "String1:String2"
    </CsScore>
    </CsoundSynthesizer>

## See also

strsubk

## Credits

Author: Istvan Varga
2006

Prev | Up | Next
strset | Home | strsubk