combinv
Prev | Orchestra Opcodes and Operators | Next

## combinv

combinv — Reverberates an input signal with a “colored” frequency response.

## Description

Reverberates an input signal with a “colored” frequency response with a FIR filter.

## Syntax

    ares combinv asig, krvt, ilpt [, iskip] [, insmps]

## Initialization

ilpt -- loop time in seconds, which determines the “echo density” of the reverberation. This in turn characterizes the “color” of the combinv filter whose frequency response curve will contain ilpt * sr/2 peaks spaced evenly between 0 and sr/2 (the Nyquist frequency). Loop time can be as large as available memory will permit. The space required for an n second loop is n*sr floating or double numbers (usually 4 or 8 bytes). Delay space is allocated and returned as in delay.

iskip (optional, default=0) -- initial disposition of delay-loop data space (cf. reson). The default value is 0.

insmps (optional, default=0) -- delay amount, as a number of samples.

## Performance

krvt -- the reverberation time (defined as the time in seconds for a signal to decay to 1/1000, or 60dB down from its original amplitude).

This filter reiterates input with an echo density determined by loop time ilpt. The attenuation rate is independent and is determined by krvt, the reverberation time (defined as the time in seconds for a signal to decay to 1/1000, or 60dB down from its original amplitude). Affect from a combinv filter will appear only after ilpt seconds.

## Examples

Here is an example of the combinv opcode. It uses the file combinv.csd.

Example 117. Example of the combinv opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o comb.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    kcps    expon p5, p3, p4
    asig	oscil3 0.3, kcps, 1
    krvt =  3.5
    ilpt =  0.1
    aleft	combinv asig, krvt, ilpt
    	outs   aleft, asig

    endin

    </CsInstruments>
    <CsScore>
    f1 0 4096 10 1
    i 1 0 3 20 2000
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

alpass, comb reverb, valpass, vcomb

## Credits

Author: John ffitch
October 2012

Prev | Up | Next
comb | Home | compress