ampdb
Prev | Orchestra Opcodes and Operators | Next

## ampdb

ampdb — Returns the amplitude equivalent of the decibel value x.

## Description

Returns the amplitude equivalent of the decibel value x. Thus:

- 60 dB = 1000

- 66 dB = 1995.262

- 72 dB = 3891.07

- 78 dB = 7943.279

- 84 dB = 15848.926

- 90 dB = 31622.764

## Syntax

    ampdb(x)  (no rate restriction)

## Examples

Here is an example of the ampdb opcode. It uses the file ampdb.csd.

Example 46. Example of the ampdb opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o ampdb.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    instr 1

    idb  =  p4
    iamp =  ampdb(idb)
    asig	oscil iamp, 220, 1
    	print iamp
    	outs  asig, asig
    endin

    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 16384 10 1

    i 1 0 1 50
    i 1 + 1 90
    i 1 + 1 68
    i 1 + 1 80

    e

    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like:

          instr 1:  iamp = 316.228
          instr 1:  iamp = 31622.763
          instr 1:  iamp = 2511.886
          instr 1:  iamp = 9999.996

## See Also

ampdbfs, db, dbamp, dbfsamp

Prev | Up | Next
alwayson | Home | ampdbfs