fmmetal
Prev | Orchestra Opcodes and Operators | Next

## fmmetal

fmmetal — Uses FM synthesis to create a “Heavy Metal” sound.

## Description

Uses FM synthesis to create a “Heavy Metal” sound. It comes from a family of FM sounds, all using 4 basic oscillators and various architectures, as used in the TX81Z synthesizer.

## Syntax

    ares fmmetal kamp, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, ifn3, \
          ifn4, ivfn

## Initialization

All these opcodes take 5 tables for initialization. The first 4 are the basic inputs and the last is the low frequency oscillator (LFO) used for vibrato. The last table should usually be a sine wave.

The initial waves should be:

- ifn1 -- sine wave

- ifn2 -- twopeaks.aiff

- ifn3 -- twopeaks.aiff

- ifn4 -- sine wave

| Note
The file “twopeaks.aiff” is also available at ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

## Performance

kamp -- Amplitude of note.

kfreq -- Frequency of note played.

kc1, kc2 -- Controls for the synthesizer:

- kc1 -- Total mod index

- kc2 -- Crossfade of two modulators

- Algorithm -- 3

kvdepth -- Vibrator depth

kvrate -- Vibrator rate

## Examples

Here is an example of the fmmetal opcode. It uses the file fmmetal.csd, and twopeaks.aiff.

Example 275. Example of the fmmetal opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o fmmetal.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kfreq = 440
    kvdepth = 0
    kvrate = 0
    ifn1 = 1
    ifn2 = 2
    ifn3 = 2
    ifn4 = 1
    ivfn = 1
    kc2  = p5

    kc1  line p4, p3, 1
    asig fmmetal .5, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, ifn3, ifn4, ivfn
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; sine wave.
    f 1 0 32768 10 1
    ; the "twopeaks.aiff" audio file.
    f 2 0 256 1 "twopeaks.aiff" 0 0 0

    i 1 0 4 6 5
    i 1 5 4 .2 10
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

fmb3, fmbell, fmpercfl, fmrhode, fmwurlie

## Credits

Author: John ffitch (after Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 3.47

Prev | Up | Next
fmbell | Home | fmpercfl